src/dawn/node/standalone/BUILD.gn

# Copyright 2026 The Dawn & Tint Authors
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this
#    list of conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice,
#    this list of conditions and the following disclaimer in the documentation
#    and/or other materials provided with the distribution.
#
# 3. Neither the name of the copyright holder nor the names of its
#    contributors may be used to endorse or promote products derived from
#    this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
# AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
# FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
# SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
# CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
# OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

import("../../../../scripts/dawn_overrides_with_defaults.gni")

if (checkout_v8 && dawn_node) {
  config("event_loop_public_config") {
    include_dirs = [ "${dawn_root}" ]
  }

  source_set("event_loop") {
    sources = [
      "EventLoop.cpp",
      "EventLoop.h",
    ]

    public_configs = [ ":event_loop_public_config" ]

    # Private: EventLoop.h only forward declares the V8 types it holds pointers
    # to, so a consumer that never runs a task needs none of this.
    include_dirs = [ "${dawn_root}/third_party/v8/src/include" ]
    deps = [
      "${dawn_root}/src/utils",
      "//third_party/v8/src:v8",
    ]

    # Public because EventLoop::Task is an absl::AnyInvocable.
    public_deps = [ "${dawn_abseil_dir}:absl" ]
  }

  config("polyfills_public_config") {
    include_dirs = [
      "${dawn_root}",
      "${dawn_root}/third_party/node-addon-api",
      "${dawn_root}/third_party/node-api-headers/include",
      "${dawn_root}/third_party/v8/src/include",
    ]
  }

  source_set("polyfills") {
    sources = [
      "Polyfills.cpp",
      "Polyfills.h",
    ]

    public_configs = [ ":polyfills_public_config" ]

    # Public because RegisterPolyfills() takes an EventLoop, so a caller needs
    # the complete type. Also forwards dawn_node_interop since Polyfills.cpp
    # includes "src/dawn/node/interop/NodeAPI.h".
    public_deps = [
      ":event_loop",
      "${dawn_root}/src/dawn/node:dawn_node_interop",
    ]

    deps = [
      "${dawn_root}/src/dawn/common",
      "${dawn_root}/src/dawn/node/napi_v8",
      "//third_party/v8/src:v8",
    ]
  }
}