third_party/directx-shader-compiler/build/generate_embedded_hlsl_headers.gni

# Copyright 2026 The Dawn & Tint Authors
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this
#    list of conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice,
#    this list of conditions and the following disclaimer in the documentation
#    and/or other materials provided with the distribution.
#
# 3. Neither the name of the copyright holder nor the names of its
#    contributors may be used to endorse or promote products derived from
#    this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
# AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
# FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
# SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
# CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
# OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

# generate_embedded_hlsl_headers aggregates hlsl snippets generated by
# embed_hlsl_header into two .inc files, as is done in the official CMake build:
# tools/clang/lib/Lex/CMakeLists.txt Invokes the same python script as the CMake
# build.
template("generate_embedded_hlsl_headers") {
  assert(defined(invoker.inputs), "must set 'inputs'")
  assert(defined(invoker.target_dir), "must set 'target_dir'")
  assert(defined(invoker.decls_output), "must set 'decls_output'")
  assert(defined(invoker.entries_output), "must set 'entries_output'")

  action(target_name) {
    script = "${invoker.dawn_dxc_dir}/utils/generate_hlsl_embedded_headers.py"
    deps = invoker.deps
    sources = invoker.inputs
    outputs = [
      invoker.decls_output,
      invoker.entries_output,
    ]

    # Script wants "--entry <base_name1>=<input1> --entry <base_name2>=<input2>"
    entries = []
    foreach(input, invoker.inputs) {
      # Turn "<invoker.target_dir>/enable_if.h.inc"
      # into "enable_if.h"
      base_name = string_replace(input, invoker.target_dir + "/", "")
      base_name = string_replace(base_name, ".inc", "")

      entries += [ "--entry" ]

      # Rebase 'input' against 'target_dir' so that the two generated files
      # produce file-relative includes.
      entries += [ "$base_name=" + rebase_path(input, invoker.target_dir) ]
    }

    args = [
             "--decls-output",
             rebase_path(invoker.decls_output, root_build_dir),
             "--entries-output",
             rebase_path(invoker.entries_output, root_build_dir),
           ] + entries
  }
}